Home > Formulas > Lookup > Hyperlink

Excel HYPERLINK Function Examples

Debra Dalgleish - Contextures

These Excel HYPERLINK function examples show how to build clickable links. Go to websites, other Excel files, or in the same Excel file. Short videos, free workbooks.

Also see hyperlink tips and hyperlink macros

Excel HYPERLINK function creates hyperlinks on worksheet

1) Video: HYPERLINK Function Examples

In this video I show a quick overview of how you can create clickable hyperlinks with Excel HYPERLINK formulas.

There are written steps and examples below the video

2) Excel HYPERLINK Function

The Excel HYPERLINK function creates hyperlinks that can open a document, or jump to a specific location.

The HYPERLINK function has two arguments in its syntax:

  • link_location: Text string for the location where you want to go
    • URL: Start with "https://"
    • Email address: Start with "mailto:"
    • Text limit - 255 characters maximum (see note below)
  • friendly_name: (optional) Text you want displayed in the cell
    • If omitted, the Link_Location is shown in the cell
    • Tip: Type a short description

hyperlink function syntax

2.1) Link_Location Character Limit

For the HYPERLINK function, there is a 255 character limit when you build the Link_Location string.

  • If you go overthe limit, the formula result will be a #VALUE error.
  • Characters are counted whether you:
    • type them into the formula, OR
    • they are in cells that the formula references

Friendly_Name: In my tests, the 255 character limit DID NOT apply to the Friendly_Name argument.

In the screen shot below, there are company names in column A, and website addresses (URLs) in column B.

In C2, I wrote a HYPERLINK formula:

  • =HYPERLINK(B2,A2)

It creates a hyperlink that goes to the URL (from B2), and shows the website name(from A2)

hyperlink formula

  • To complete the list of hyperlinks, I copied the formula from C2, down to the remaining rows.

4) Video: Link to Excel Files

With a HYPERLINK formula, you can link to a location in the current Excel workbook, or to another Excel file. This video shows the steps, and there are written steps below the video.

TIP: To follow along with this video, download the Hyperlink Examples Video workbook.

5) Example - Link to Another Excel File

You can link to other Excel files that are in the same folder as the active file, or in a different folder.

5.1) Other File in Same Folder

To create a link to a different workbook, in the same folder, just use the file name as the link_location argument for the HYPERLINK function.

  • =HYPERLINK("MyFileC.xlsx","FileC")

5.2) Other File in Different Folder

For files that are up a level or more in the hierarchy, use two periods and a backslash for each level.

  • In this example, the file is 1 level up.
  • =HYPERLINK("..\MyFileB.xlsx","FileB")

  • In this example, the file is 2 levels up.
  • =HYPERLINK("..\..\MyFileA.xlsx","FileA")

5,2,1) Use Cell References

Or, instead of typing the file path details in the HYPERLINK formula, you can refer to cells that contain the location text.

In the screen shot below, the formula in cell E3 refers to the address in C3, and the friendly name in cell D3:

  • =HYPERLINK(C3, D3)

link to other files in same folder

6) Example - Link in Same Excel File

You can use a HYPERLINK formula to create a link that goes to a cell or range somewhere within the current workbook.

  • Important: You must add a pound sign (#) at the start of the address in the HYPERLINK formula

Below, there are 6 examples for HYPERLINK formulas within the same workbook:

6.1) Type the Address

Start with a #, then type the sheet name and cell reference.

Optional - Type a friendly name, such as "Budget" to appear in the cell:

  • =HYPERLINK("#Sheet2!B2","Budget")

Tip: If the formula's hyperlink doesn't work, insert a temporary hyperlink in a blank cell, using the Ctrl + K shortcut. Use its location syntax as a guide to fixing your formula.

6.2) Use Cell References

Use the & operator to create a link location.

In this example, the sheet name is in cell B5, the cell address is in C5, and the friendly name is in cell D5.

  • =HYPERLINK("#"&"'" & B5 & "'!" & C5,D5)

hyperlink formula

6.3) Type a Range Name

For a link to a workbook-level named range in the same workbook, just use the range name as the link location.

  • =HYPERLINK("#StartCell","StartCell")

7) HYPERLINK Examples - Advanced

The examples in the following sections go beyond the basics. They show the power and versatility of the Excel HYPERLINK function.

8) Hyperlink to Next Empty Cell

Go to the empty cell at the end of:

  1. a worksheet list
  2. a named table.

hyperlink formula

8.1 - Worksheet List

In cell B1, the formula finds the first empty cell after the worksheet list in column A:

  • =HYPERLINK("#A" & COUNTA(A:A) + ROW(A3), "Add Entry")

To find the empty row number, add the count of items in column A, plus the row number for the starting cell.

hyperlink formula

8.2 - Named Table

In cell E1, the formula finds the first empty cell after the named table in column D:

  • =HYPERLINK("#D" & SUM(COUNTA(tblDays[Day]), ROW(tblDays[[#Headers], [Day]]), 1), "Add Entry")

Here's how the formula works.

To find the empty row number, the formula calculates the SUM of:

  • The table's starting row (3)
    • =ROW(tblDays[[#Headers],[Day]])
  • The number of data rows in the table (3)
    • =COUNTA(tblDays[Day])
  • Plus one, to get to the empty cell below the table (1)

In the screen shot below, the empty cell's row number is 7:

  • 3 + 3 + 1 = 7

hyperlink formula

9) Sheet Navigation No Macros

In some large Excel workbooks, I add hyperlinks that go to the previous sheet and next sheet quickly.

In the Sheet Navigation sample file, shown below, each sheet has hyperlinks created with the HYPERLINK function.

  • Click a hyperlink to go to the Previous or Next worksheet
  • Or select a sheet name, and click the Go hyperlink

sheet navigation with hyperlinks no macros

9.1) How It Works

On a worksheet named Lists, there are two things that help the navigation system work:

  • a list of the sheets that you want to navigate to
  • a formula that counts the tables names in the list.

named table with list of sheets and sheet count formula

9.1.1) HYPERLINK Formulas

For sheet navigation, there are formulas in columns A (visible) and B (hidden)

  • Col A - HYPERLINK formulas for Prev, Next and Go hyperlinks.
    • There's a drop down list of sheet names in A5
  • Col B - Formulas calculate the active sheet name, its position in the sheet list, and the position and names of the Prev and Next sheets

formulas in hidden column B

10) Get the Excel Files ✅

  1. HYPERLINK Examples: To see the hyperlink examples, Hyperlink function examples and macro, you can download the Excel Hyperlink sample file. The file is in xlsm format, zipped, and contains macros. Enable macros if you want to use the sample code.
  2. Sheet Navigation No Macros: In the Sheet Navigation sample file, each main sheet has HYPERLINK formulas that create hyperlinks to the next and previous sheets. No macros required -- the formulas do all the work.

Get Monthly Excel Tips!

Don't miss my monthly Excel newsletter! You'll get quick tips, article links, and a bit of fun. Add your email, and click Sign Up.

Next, when you get my reply, click the Confirm button. I add this step to protect you from spam!

More Tutorials

Hyperlink Tips

Hyperlink Macros

Pivot Table Hyperlinks

 

 

Last updated: August 19, 2026 4:07 PM