These Excel advanced filter examples take you **beyond the basic steps**. See how to find top records, blank cells, date range, and more. There are written steps, videos, and a sample file to download.

This video shows the steps for setting up a criteria range, and running an Advanced Filter. The examples below show how to set up more complicated criteria, such as finding rows with blank cells.

For the written steps on setting up a basic Excel Advanced Filter, go to the Advanced Filter Introduction page.

Most of the examples below use formulas in the criteria area. When you use a formula:

- Leave the criteria heading cell blank,
**Or**, use a heading that is different from any of the table headings

This video shows an example.

To follow along with the examples on this page, get the Excel workbook with these Advanced Filter criteria examples. The zipped workbook is in xlsx format, and does not contain any macros.

To get the Top 5 records with an Advanced Filter, or any other number of top records, use the **LARGE** function in the criteria, to find rows with the
highest values.

Because there is a formula in cell F2, the criteria heading (F1) is left blank.

- F1: Criteria Heading -- Leave blank
- F2: Criteria:
**=D2>=LARGE($D$2:$D$28,5)**

- The LARGE function returns the 5th largest value in the range D2:D28
- An absolute reference is used for the data range --
**$D$2:$D$28**

- An absolute reference is used for the data range --
- Cell D2, the first cell with data in the Total column, is compared
to that value.
- A relative reference is used for D2, so the total in each row is checked

- Rows with
a Total greater than or equal to the 5th largest number
are shown in the results
- In the case of ties, more than five records may be returned)

Instead of typing 5 in the formula, put that number in a cell, and refer to that cell in the criteria formula.

**=D2>=LARGE($D$2:$D$28,G2)**

This makes it easy to change the "Top 5" into the "Top 10" or any other number.

In this example, the filter will extract the five records with highest totals, for records that were entered on or after a specific date. If you download the sample file, there is also an example for finding the highest totals within a specific date range.

NOTE: To see the steps for showing top 10 based on additional criteria in an AutoFilter, go to my blog post on Top 10 in Filtered Rows

- H2: Type the starting date for the filtered records (Feb 3 in this
example)

I2: Type the number of top records to return (5 in this example)

K2: Formula calculates the number of records after the start date:**=COUNTIF($A$3:$A$29,">=" & $H$2)**

M2: Formula calculates 5th largest Total for orders on or after Feb 3rd**=LARGE(IF($A$3:$A$29>=$H$2, $D$3:$D$29), MIN($K$2,$I$2))**

- F1: Criteria Heading -- Leave blank
- F2: Criteria:
**=AND(A3>=$H$2,D3>=$M$2)**

- The LARGE function returns the fifth largest value in the range
D3:D29, for dates on or after Feb 3rd.

An absolute reference is used for each range, such as $A$3:$A$29. - NOTE: This formula is arrayed enterd (Ctrl+Shift+Enter), to create
a LARGE IF formula -- it returns the 5th largest total for the records
**IF**the date is greater than Feb 3rd. - NOTE: If there are fewer records than the Top # entered, the lower
number is used --
**MIN($K$2,$I$2)**

In cell F2, the criteria formula checks two things:

- Cell A3, the first cell with data in the Date column, is compared to this value. A relative reference is used for this -- A3.
- Rows with a Total value that is greater than or equal to the fifth largest number, and a date on or after Feb 3rd, pass through the Excel advanced filter. (Note: In the case of ties, more than five records may be returned)
- The AND function adds a second criiteria to the filter -- the
total must be greater than the minimum calculated in cell M2
**AND(.....D3>=$M$2)**

In the screen shot below, the top five records with dates on or after Feb 3rd are in the filtered results.

This Advanced Filter criteria example extracts records where there is a matching value in two columns -- the Ordered date must be equal to the Shipped date.

Here's what's in the criteria range, in column F. The heading cell is left blank, because the criterion is a formula:

- F1: Criteria Heading -- Leave blank
- F2: Criteria:
**=C2=D2**

In each record, the Order date is compared to the Ship date. A relative reference is used for this -- C2 and D2.

The Excel Advanced Filter extracts the rows where the two dates are equal .

To see the steps for creating an Advanced Filter for unmatched amounts in a row, please watch this short video. The written instructions are shown below.

F1: Criteria Heading -- Leave blank

F2: Criteria: ** =C2<>D2**

In each record, the Invoice amount is compared to the amount Paid. A relative reference is used for this -- C2 and D2. Rows where the amounts are not equal are displayed.

**Note**: You can use a column heading in the criteria formula,
instead of a cell reference. The formula will return the #NAME? or
#VALUE! error, but the filter will work correctly. For example:

F2: Criteria: ** =Invoice<>Paid**

F1: Criteria Heading -- Leave blank

F2: Criteria: ** =ISNUMBER(FIND("8",C2))**

The FIND function looks for the string "8" in the contents
of cell C2.

If it finds the number, the result is the location of the number in
the string. If the number is not found, an Error is the result.

This video shows the steps for creating an Advanced Filter for rows with blank cells, please watch this short video. The written instructions are shown below the video.

This is the option shown in the video, above. Use these criteria range settings to filter rows with blank cells

- F1: Criteria Heading -- Leave blank
- F2: Criteria:
**=C2=""**

In each record, the value in column C is checked. If it is an empty string, the record passes through the Excel advanced filter.

Use these criteria range settings to filter rows with blank cells

- F1: Criteria Heading -- Product (this is an exact match for the column heading)
- F2: Criteria:
**="="**

In each record, the value in column C is checked. If the cell is empty, the record passes through the Excel advanced filter.

You can create a list of items on a worksheet, then filter another list, to show only the records that contain those items. There are 2 examples below:

- Filter rows that have an
**exact match for items**in the list - Filter rows that
**contain an item**in the list, anywhere in the cell

The COUNTIF function is used in the Criteria range, to check each record, and test for the list items. Rows with an exact match are returned in the filter. Written instructions are below the video.

Two criteria are used in this advanced filter

- total must be greater than 1000
- product must be in the list in column I

NOTE: To filter the results to a different sheet, start the filter from the destination sheet. See the details here.

To set up the Advanced Filter:

- In Column I, enter the list of items that you want to match -- Bread and Cookies, in this example.
- Enter the following values/formulas in the Criteria range:
- F1: Criteria Heading -- "Total"
- F2: Criteria:
**>1000** - G1: Criteria Heading -- Leave blank
- G2: Criteria:
**=COUNTIF(I:I,C2)**

In each record, the value in column C is checked. If it is in the list in column I, and the total is greater than 1000, the record passes through the Excel advanced filter.

The SUMPRODUCT and COUNTIF functions are used in the Criteria range, to check each record, and test for the list items. Rows that contain an item in the list, anywhere in the Product cell, are returned in the filter.

Two criteria are used in this advanced filter

- total must be greater than 100
- product must contain an item in the list in column I, anywhere in the product cell

To set up the Advanced Filter:

- In Column I, enter the list of items that you want to match -- Bread and Cookies, in this example.
- Format the list as a named Excel Table (tblFind in this example)
- Name the list of items in the table. In this example, the list is named
**FindList**. - Enter the following values/formulas in the Criteria range:
- F1: Criteria Heading -- "Total"
- F2: Criteria:
**>100** - G1: Criteria Heading -- Leave blank
- G2: Criteria:
**=SUMPRODUCT(COUNTIF(C2,"*"& FindList &"*"))>0**

In each record, the value in column C is checked. If it contains an item from the list in column I, and the total is greater than 100, the record passes through the Excel advanced filter.

Get the Excel workbook with these Advanced Filter criteria examples. The zipped workbook is in xlsx format, and does not contain any macros.

Last updated: August 1, 2021 3:25 PM